Add support for Benesse Pocket Challenge W Module (thx to skaman)

Cart_Reader/Cart_Reader.ino

@@ -4,8 +4,8 @@
    This project represents a community-driven effort to provide
    an easy to build and easy to modify cartridge dumper.
 
-   Date:             18.09.2022
+   Date:             25.09.2022
-   Version:          9.8
+   Version:          9.9
 
    SD lib: https://github.com/greiman/SdFat
    OLED lib: https://github.com/adafruit/Adafruit_SSD1306
@@ -24,7 +24,7 @@
    MichlK - ROM Reader for Super Nintendo
    Jeff Saltzman - 4-Way Button
    Wayne and Layne - Video Game Shield menu
-   skaman - Cart ROM READER SNES ENHANCED, Famicom Cart Dumper, Coleco-, Intellivision, Virtual Boy, WSV modules
+   skaman - Cart ROM READER SNES ENHANCED, Famicom Cart Dumper, Coleco-, Intellivision, Virtual Boy, WSV, PCW modules
    Tamanegi_taro - PCE and Satellaview modules
    splash5 - GBSmart, Wonderswan and NGP modules
    hkz & themanbehindthecurtain - N64 flashram commands
@@ -59,7 +59,7 @@
 
 **********************************************************************************/
 
-char ver[5] = "9.8";
+char ver[5] = "9.9";
 
 //******************************************
 // !!! CHOOSE HARDWARE VERSION !!!
@@ -97,6 +97,7 @@ char ver[5] = "9.8";
 // #define enable_COLV
 // #define enable_VBOY
 // #define enable_WSV
+// #define enable_PCW
 
 //******************************************
 // HW CONFIGS
@@ -300,6 +301,7 @@ bool i2c_found;
 #define mode_COL 24
 #define mode_VBOY 25
 #define mode_WSV 26
+#define mode_PCW 27
 
 // optimization-safe nop delay
 #define NOP __asm__ __volatile__ ("nop\n\t")
@@ -804,9 +806,10 @@ static const char modeItem10[] PROGMEM = "Intellvision";
 static const char modeItem11[] PROGMEM = "Colecovision";
 static const char modeItem12[] PROGMEM = "Virtual Boy";
 static const char modeItem13[] PROGMEM = "Watara Supervision";
-static const char modeItem14[] PROGMEM = "Flashrom Programmer";
+static const char modeItem14[] PROGMEM = "Pocket Challenge W";
-static const char modeItem15[] PROGMEM = "About";
+static const char modeItem15[] PROGMEM = "Flashrom Programmer";
-static const char* const modeOptions[] PROGMEM = {modeItem1, modeItem2, modeItem3, modeItem4, modeItem5, modeItem6, modeItem7, modeItem8, modeItem9, modeItem10, modeItem11, modeItem12, modeItem13, modeItem14, modeItem15};
+static const char modeItem16[] PROGMEM = "About";
+static const char* const modeOptions[] PROGMEM = {modeItem1, modeItem2, modeItem3, modeItem4, modeItem5, modeItem6, modeItem7, modeItem8, modeItem9, modeItem10, modeItem11, modeItem12, modeItem13, modeItem14, modeItem15, modeItem16};
 
 // All included slots
 void mainMenu() {
@@ -831,8 +834,8 @@ void mainMenu() {
     }
     if (currPage == 3) {
       // Copy menuOptions out of progmem
-      convertPgm(modeOptions, 14, 1);
+      convertPgm(modeOptions, 14, 2);
-      modeMenu = question_box(F("OPEN SOURCE CART READER"), menuOptions, 1, 0);
+      modeMenu = question_box(F("OPEN SOURCE CART READER"), menuOptions, 2, 0);
     }
     if (numPages == 0) {
       // Execute choice
@@ -945,8 +948,15 @@ void mainMenu() {
       break;
 #endif
 
-#ifdef enable_FLASH
+#ifdef enable_PCW
     case 13:
+      setup_PCW();
+      pcwMenu();
+      break;
+#endif
+
+#ifdef enable_FLASH
+    case 14:
 #ifdef enable_FLASH16
       flashMenu();
 #else
@@ -955,7 +965,7 @@ void mainMenu() {
       break;
 #endif
 
-    case 14:
+    case 15:
       aboutScreen();
       break;
 
@@ -1002,8 +1012,9 @@ static const char handheldsItem1[] PROGMEM = "Virtual Boy";
 static const char handheldsItem2[] PROGMEM = "WonderSwan";
 static const char handheldsItem3[] PROGMEM = "NeoGeo Pocket";
 static const char handheldsItem4[] PROGMEM = "Watara Supervision";
-static const char handheldsItem5[] PROGMEM = "Reset";
+static const char handheldsItem5[] PROGMEM = "Pocket Challenge W";
-static const char* const handheldsOptions[] PROGMEM = {handheldsItem1, handheldsItem2, handheldsItem3, handheldsItem4, handheldsItem5};
+static const char handheldsItem6[] PROGMEM = "Reset";
+static const char* const handheldsOptions[] PROGMEM = {handheldsItem1, handheldsItem2, handheldsItem3, handheldsItem4, handheldsItem5, handheldsItem6};
 
 // All included slots
 void mainMenu() {
@@ -1160,11 +1171,11 @@ void consoleMenu() {
 
 // Everything that needs an adapter
 void handheldMenu() {
-  // create menu with title and 5 options to choose from
+  // create menu with title and 6 options to choose from
   unsigned char handheldsMenu;
   // Copy menuOptions out of progmem
-  convertPgm(handheldsOptions, 5);
+  convertPgm(handheldsOptions, 6);
-  handheldsMenu = question_box(F("Choose Adapter"), menuOptions, 5, 0);
+  handheldsMenu = question_box(F("Choose Adapter"), menuOptions, 6, 0);
 
   // wait for user choice to come back from the question box menu
   switch (handheldsMenu)
@@ -1201,7 +1212,14 @@ void handheldMenu() {
       break;
 #endif
 
+#ifdef enable_PCW
     case 4:
+      setup_PCW();
+      pcwMenu();
+      break;
+#endif
+
+    case 5:
       resetArduino();
       break;
 
@@ -3403,6 +3421,11 @@ void loop() {
   else if (mode == mode_WSV) {
     wsvMenu();
   }
+#endif
+#ifdef enable_PCW
+  else if (mode == mode_PCW) {
+    pcwMenu();
+  }
 #endif
   else {
     display_Clear();

Cart_Reader/GB.ino

@@ -428,7 +428,7 @@ void showCartInfo_GB() {
       print_Msg(F("HuC-1"));
     else if (romType == 0x104)
       print_Msg(F("M161"));
-    
+
     println_Msg(F(" "));
     print_Msg(F("Rom Size: "));
     switch (romSize) {
@@ -800,17 +800,17 @@ void getCartInfo_GB() {
   if (sdBuffer[0x143] == 0x80 || sdBuffer[0x143] == 0xC0) {
     x++;
   }
-  for (int addr = 0x0134; addr <= 0x0143-x; addr++) {
+  for (int addr = 0x0134; addr <= 0x0143 - x; addr++) {
     myByte = sdBuffer[addr];
     if (isprint(myByte) && myByte != '<' && myByte != '>' && myByte != ':' && myByte != '"' && myByte != '/' && myByte != '\\' && myByte != '|' && myByte != '?' && myByte != '*') {
       romName[myLength] = char(myByte);
     } else {
-      if (romName[myLength-1] == 0x5F) myLength--;
+      if (romName[myLength - 1] == 0x5F) myLength--;
       romName[myLength] = 0x5F;
     }
     myLength++;
   }
-  
+
   // Strip trailing white space
   for (unsigned int i = myLength - 1; i > 0; i--) {
     if ((romName[i] != 0x5F) && (romName[i] != 0x20)) break;
@@ -871,13 +871,13 @@ void readROM_GB() {
   uint32_t processedProgressBar = 0;
   uint32_t totalProgressBar = (uint32_t)(romBanks) * 16384;
   draw_progressbar(0, totalProgressBar);
-  
+
   // M161 banks are double size and start with 0
   if (romType == 0x104) {
     startBank = 0;
     romBanks >>= 1;
   }
-  
+
   for (word currBank = startBank; currBank < romBanks; currBank++) {
     // Second bank starts at 0x4000
     if (currBank > 1) {
@@ -893,7 +893,7 @@ void readROM_GB() {
       PORTH |= (1 << 0);
       writeByte_GB(0x4000, currBank & 0x7);
     }
-    
+
     // Set ROM bank for MBC2/3/4/5
     else if (romType >= 5) {
       if (romType >= 11 && romType <= 13) {

Cart_Reader/GBA.ino

@@ -898,19 +898,19 @@ void getCartInfo_GBA() {
       if (isprint(myByte) && myByte != '<' && myByte != '>' && myByte != ':' && myByte != '"' && myByte != '/' && myByte != '\\' && myByte != '|' && myByte != '?' && myByte != '*') {
         romName[myLength] = char(myByte);
       } else {
-        if (romName[myLength-1] == 0x5F) myLength--;
+        if (romName[myLength - 1] == 0x5F) myLength--;
         romName[myLength] = 0x5F;
       }
       myLength++;
     }
-    
+
     // Strip trailing white space
     for (unsigned int i = myLength - 1; i > 0; i--) {
       if ((romName[i] != 0x5F) && (romName[i] != 0x20)) break;
       romName[i] = 0x00;
       myLength--;
     }
-    
+
     // Get ROM version
     romVersion = sdBuffer[0xBC];
 

Cart_Reader/MD.ino

@@ -2452,7 +2452,7 @@ void readRealtec_MD() {
   strcat(fileName, ".MD");
 
   // create a new folder
-  EEPROM_readAnything(10, foldern);
+  EEPROM_readAnything(0, foldern);
   sprintf(folder, "MD/ROM/%s/%d", romName, foldern);
   sd.mkdir(folder, true);
   sd.chdir(folder);
@@ -2465,7 +2465,7 @@ void readRealtec_MD() {
 
   // write new folder number back to eeprom
   foldern = foldern + 1;
-  EEPROM_writeAnything(10, foldern);
+  EEPROM_writeAnything(0, foldern);
 
   // Open file on sd card
   if (!myFile.open(fileName, O_RDWR | O_CREAT)) {

Cart_Reader/N64.ino

@@ -2718,12 +2718,12 @@ void idCart() {
     if (isprint(myByte) && myByte != '<' && myByte != '>' && myByte != ':' && myByte != '"' && myByte != '/' && myByte != '\\' && myByte != '|' && myByte != '?' && myByte != '*') {
       romName[myLength] = char(myByte);
     } else {
-      if (romName[myLength-1] == 0x5F) myLength--;
+      if (romName[myLength - 1] == 0x5F) myLength--;
       romName[myLength] = 0x5F;
     }
     myLength++;
   }
-  
+
   // Strip trailing white space
   for (unsigned int i = myLength - 1; i > 0; i--) {
     if ((romName[i] != 0x5F) && (romName[i] != 0x20)) break;

Cart_Reader/PCW.ino

@@ -0,0 +1,607 @@
+//******************************************
+// BENESSE POCKET CHALLENGE W MODULE
+//******************************************
+// Benesse Pocket Challenge W
+// Cartridge Pinout
+// 38P 1.27mm pitch connector
+//
+// CART            CART
+// TOP             EDGE
+//     +---------+
+//     |   1   |-- VCC
+//     |   2   |-- GND
+//     |   3   |-- AD0 (A0 IN/D0 OUT)
+//     |   4   |-- AD1 (A1 IN/D1 OUT)
+//     |   5   |-- AD2 (A2 IN/D2 OUT)
+//     |   6   |-- AD3 (A3 IN/D3 OUT)
+//     |   7   |-- AD4 (A4 IN/D4 OUT)
+//     |   8   |-- AD5 (A5 IN/D5 OUT)
+//     |   9   |-- AD6 (A6 IN/D6 OUT)
+//     |  10   |-- AD7 (A7 IN/D7 OUT)
+//     |  11   |-- A08
+//     |  12   |-- A09
+//     |  13   |-- A10
+//     |  14   |-- A11
+//     |  15   |-- A12
+//     |  16   |-- A13
+//     |  17   |-- A14
+//     |  18   |-- A15
+//     |  19   |-- A16
+//     |  20   |-- A17
+//     |  21   |-- A18
+//     |  22   |-- A19
+//     |  23   |-- A20
+//     |  24   |-- A21
+//     |  25   |-- NC [CPU-INT2/T15(P47)]
+//     |  26   |-- 1B (7W00F) -> HIGH -+
+//     |  27   |-- 1A (7W00F) -> HIGH -+-> OE (ROM) = LOW
+//     |  28   |-- OE (LH5164A)
+//     |  29   |-- WE (LH5164A)
+//     |  30   |-- LE (HC573) [LATCH ENABLE FOR AD0-AD7]
+//     |  31   |-- NC [CPU-TO5(P43)]
+//     |  32   |-- NC [CPU-RESET]
+//     |  33   |-- VCC
+//     |  34   |-- GND
+//     |  35   |-- NC
+//     |  36   |-- NC [CPU-VCC]
+//     |  37   |-- NC [CONSOLE-GND]
+//     |  38   |-- NC
+//     +---------+
+
+// CONTROL PINS:
+// LE - (PH0) - PCW PIN 30 - SNES RST
+// 1A - (PH3) - PCW PIN 27 - SNES /CS
+// 1B - (PH4) - PCW PIN 26 - SNES /IRQ
+// WE - (PH5) - PCW PIN 29 - SNES /WR
+// OE - (PH6) - PCW PIN 28 - SNES /RD
+
+// NOT CONNECTED:
+// CLK(PH1) - N/C
+
+// ADDRESS PINS:
+// ADDR/DATA [AD0-AD7] - PORTC
+// ADDR A8-A15 - PORTK
+// ADDR A16-A21 - PORTL
+
+//******************************************
+// DEFINES
+//******************************************
+
+// CONTROL PINS - LE/1A/1B/WE/OE
+#define LE_HIGH PORTH |= (1 << 0)
+#define LE_LOW PORTH &= ~(1 << 0)
+#define NAND_1A_HIGH PORTH |= (1 << 3)
+#define NAND_1A_LOW PORTH &= ~(1 << 3)
+#define NAND_1B_HIGH PORTH |= (1 << 4)
+#define NAND_1B_LOW PORTH &= ~(1 << 4) // Built-in RAM + I/O
+#define WE_HIGH PORTH |= (1 << 5)
+#define WE_LOW PORTH &= ~(1 << 5)
+#define OE_HIGH PORTH |= (1 << 6)
+#define OE_LOW PORTH &= ~(1 << 6)
+
+#define MODE_READ DDRC = 0 // [INPUT]
+#define MODE_WRITE DDRC = 0xFF //[OUTPUT]
+
+#define DATA_READ { DDRC = 0; PORTC = 0xFF; } // [INPUT PULLUP]
+#define ADDR_WRITE DDRC = 0xFF // [OUTPUT]
+
+boolean multipack = 0; // Multi-Pack Cart
+byte bank0;
+byte bank1;
+
+//******************************************
+// SETUP
+//******************************************
+
+void setup_PCW() {
+  // Set Address Pins to Output
+  //A8-A15
+  DDRK = 0xFF;
+  //A16-A21
+  DDRL = 0xFF;
+
+  // Set Control Pins to Output
+  //       LE(PH0)    --(PH1)    1A(PH3)    1B(PH4)    WE(PH5)    OE(PH6)
+  DDRH |= (1 << 0) | (1 << 1) | (1 << 3) | (1 << 4) | (1 << 5) | (1 << 6);
+
+  // Set TIME(PJ0) to Output (UNUSED)
+  DDRJ |=  (1 << 0);
+
+  // Set Address/Data Pins AD0-AD7 (PC0-PC7) to Input
+  MODE_READ; // DDRC = 0
+
+  // Setting Control Pins to HIGH
+  //        LE(PH0)   ---(PH1)    1A(PH3)    1B(PH4)    WE(PH5)    OE(PH6)
+  PORTH |= (1 << 0) | (1 << 1) | (1 << 3) | (1 << 4) | (1 << 5) | (1 << 6);
+
+  // Set Unused Pins HIGH
+  PORTJ |= (1 << 0); // TIME(PJ0)
+
+  // Multi-Pack Cart Check
+  check_multi_PCW();
+
+  strcpy(romName, "PCW");
+
+  mode = mode_PCW;
+}
+
+//******************************************
+//  MENU
+//******************************************
+static const char pcwmenuItem1[] PROGMEM = "Read ROM";
+static const char pcwmenuItem2[] PROGMEM = "Read SRAM";
+static const char pcwmenuItem3[] PROGMEM = "Write SRAM";
+static const char pcwmenuItem4[] PROGMEM = "Reset";
+static const char* const menuOptionsPCW[] PROGMEM = {pcwmenuItem1, pcwmenuItem2, pcwmenuItem3, pcwmenuItem4};
+
+void pcwMenu()
+{
+  convertPgm(menuOptionsPCW, 4);
+  uint8_t mainMenu = question_box(F(" POCKET CHALLENGE W"), menuOptions, 4, 0);
+
+  switch (mainMenu)
+  {
+    case 0:
+      // Read ROM
+      sd.chdir("/");
+      if (multipack)
+        readMultiROM_PCW();
+      else
+        readROM_PCW();
+      sd.chdir("/");
+      break;
+
+    case 1:
+      // Read SRAM
+      sd.chdir("/");
+      display_Clear();
+      println_Msg(F("Reading SRAM..."));
+      display_Update();
+      readSRAM_PCW();
+      sd.chdir("/");
+      // Wait for user input
+      println_Msg(F("Press Button..."));
+      display_Update();
+      wait();
+      break;
+
+    case 2:
+      // Write SRAM
+      sd.chdir("/");
+      fileBrowser(F("Select SRM file"));
+      display_Clear();
+      writeSRAM_PCW();
+      display_Clear();
+      writeErrors = verifySRAM_PCW();
+      if (writeErrors == 0) {
+        println_Msg(F("SRAM verified OK"));
+        display_Update();
+      }
+      else {
+        print_Msg(F("Error: "));
+        print_Msg(writeErrors);
+        println_Msg(F(" bytes "));
+        print_Error(F("did not verify."), false);
+      }
+      break;
+
+    case 3:
+      // Reset
+      resetArduino();
+      break;
+  }
+}
+
+//******************************************
+//  LOW LEVEL FUNCTIONS
+//******************************************
+
+// Max ROM Size 0x400000 (Highest Address = 0x3FFFFF) - 3F FFFF
+// NAND 1A + 1B HIGH = LOW = ROM Output Enabled
+void read_setup_PCW() {
+  NAND_1A_HIGH;
+  NAND_1B_HIGH;
+  OE_HIGH;
+  WE_HIGH;
+  LE_LOW;
+}
+
+// READ ROM BYTE WITH ADDITIONAL DELAY
+// NEEDED FOR PROBLEM CARTS TO SWITCH FROM ADDRESS TO DATA
+unsigned char read_rom_byte_PCW(unsigned long address) {
+  PORTL = (address >> 16) & 0xFF;
+  PORTK = (address >> 8) & 0xFF;
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = address & 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  __asm__("nop\n\t""nop\n\t");
+  // Read Data on AD0-AD7
+  OE_LOW;
+  DATA_READ;
+  delayMicroseconds(5); // 3+ Microseconds for Problem Carts
+  unsigned char data = PINC;
+  OE_HIGH;
+
+  return data;
+}
+
+// SRAM Size 0x8000 (Highest Address = 0x7FFF)
+// NAND 1A LOW = SRAM Enabled [ROM DISABLED]
+unsigned char read_ram_byte_1A_PCW(unsigned long address) {
+  NAND_1A_LOW;
+  PORTL = (address >> 16) & 0xFF;
+  PORTK = (address >> 8) & 0xFF;
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = address & 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  // Read Data on AD0-AD7
+  OE_LOW;
+  DATA_READ;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  unsigned char data = PINC;
+  OE_HIGH;
+  NAND_1A_HIGH;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+
+  return data;
+}
+
+// Toshiba TMP90C845A
+// 0xFEC0-0xFFBF Built-in RAM (256 bytes)
+// 0xFFC0-0xFFF7 Built-in I/O (56 bytes)
+// 0xFF00-0xFFBF (192 byte area available in direct addressing mode)
+// 0xFF18-0xFF68 (Micro DMA parameters (if used))
+
+// TEST CODE TO READ THE CPU BUILT-IN RAM + I/O
+// NAND 1B LOW = Built-In RAM + I/O Enabled [ROM DISABLED]
+unsigned char read_ram_byte_1B_PCW(unsigned long address) {
+  NAND_1B_LOW;
+  PORTL = (address >> 16) & 0xFF;
+  PORTK = (address >> 8) & 0xFF;
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = address & 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  // Read Data on AD0-AD7
+  OE_LOW;
+  DATA_READ;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  unsigned char data = PINC;
+  OE_HIGH;
+  NAND_1B_HIGH;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+
+  return data;
+}
+
+// WRITE SRAM 32K
+void write_ram_byte_1A_PCW(unsigned long address, unsigned char data) {
+  NAND_1A_LOW;
+  PORTL = (address >> 16) & 0xFF;
+  PORTK = (address >> 8) & 0xFF;
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = address & 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  // Write Data on AD0-AD7 - WE LOW ~240-248ns
+  WE_LOW;
+  PORTC = data;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  WE_HIGH;
+  NAND_1A_HIGH;
+}
+
+// WRITE CPU BUILT-IN RAM + I/O AREA
+// MODIFIED TO MATCH WORKING BANK SWITCH ROUTINE
+void write_ram_byte_1B_PCW(unsigned long address, unsigned char data) {
+  NAND_1A_LOW;
+  NAND_1A_HIGH;
+  NAND_1B_LOW;
+  PORTL = (address >> 16) & 0xFF;
+  PORTK = (address >> 8) & 0xFF;
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = address & 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  // Write Data on AD0-AD7 - WE LOW ~740ns
+  WE_LOW;
+  PORTC = data;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  WE_HIGH;
+  NAND_1B_HIGH;
+}
+
+//==============================================================================
+// Overload Multi-Pack Bank Switch
+//
+// Known Multi-Pack Carts (Yellow Label Carts)
+// 0BD400 [PS] (2MB Version)
+// 0BD400 [PS] (4MB Version)
+// 0BF400 [PL]
+// 1BF400 [PZ]
+// 8BD400 [CR]
+// 8BF400 [LP]
+// 9BF400 [SLP] (Undumped)
+
+// Per Overload, identify multi-pack cart by reading 0x3FFA-0x3FFE
+// Multi-Pack carts are non-zero
+// 0x3FFA - Current Cartridge Bank
+// 0x3FFC - Value to Switch to Cartridge Bank 0
+// 0x3FFD - Value to Switch to Cartridge Bank 1
+// 0x3FFE - Last Value written to 0xFFFF
+
+// Bank Settings for 2MB
+// Write 0x28 to 0xFFFF to read 1st half of ROM
+// Write 0x2E to 0xFFFF to read 2nd half of ROM
+
+// Bank Settings for 4MB
+// Write 0x20 to 0xFFFF to read 1st half of ROM
+// Write 0x31 to 0xFFFF to read 2nd half of ROM
+
+// MULTI-PACK CART CHECK
+void check_multi_PCW() {
+  read_setup_PCW();
+  byte tempbyte = read_rom_byte_PCW(0x3FFC); // Bank 0 Switch
+  if (tempbyte) {
+    bank0 = tempbyte; // Store Bank 0 Switch
+    tempbyte = read_rom_byte_PCW(0x3FFD); // Bank 1 Switch
+    if (tempbyte) {
+      bank1 = tempbyte; // Store Bank 1 Switch
+      // Check for 00s
+      tempbyte = read_rom_byte_PCW(0x3FFB); // Should be 00
+      if (!tempbyte) {
+        tempbyte = read_rom_byte_PCW(0x3FFF); // Should be 00
+        if (!tempbyte)
+          multipack = 1; // Flag Multi-Cart
+        else {
+          bank0 = 0;
+          bank1 = 0;
+        }
+      }
+    }
+  }
+}
+
+void write_bank_byte_PCW(unsigned char data) {
+  NAND_1A_LOW;
+  NAND_1A_HIGH;
+  NAND_1B_LOW;
+  // Write to Address 0xFFFF
+  PORTL = 0x00;
+  PORTK = 0xFF; // A8-A15
+  // Latch Address on AD0-AD7
+  ADDR_WRITE;
+  LE_HIGH; // Latch Enable
+  PORTC = 0xFF; // A0-A7
+  LE_LOW; // Address Latched
+  // Write Data on AD0-AD7 - WE LOW ~728-736ns
+  WE_LOW;
+  PORTC = data;
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  __asm__("nop\n\t""nop\n\t""nop\n\t""nop\n\t""nop\n\t");
+  WE_HIGH;
+  NAND_1B_HIGH;
+}
+
+void switchBank_PCW(int bank) {
+  if (bank == 1) { // Upper Half
+    write_bank_byte_PCW(bank1);
+  }
+  else { // Lower Half (default)
+    write_bank_byte_PCW(bank0);
+  }
+}
+
+//******************************************
+// READ CODE
+//******************************************
+
+void readROM_PCW() {
+  strcpy(fileName, romName);
+  strcat(fileName, ".pcw");
+
+  EEPROM_readAnything(0, foldern);
+  sprintf(folder, "PCW/ROM/%d", foldern);
+  sd.mkdir(folder, true);
+  sd.chdir(folder);
+
+  display_Clear();
+  print_Msg(F("Saving to "));
+  print_Msg(folder);
+  println_Msg(F("/..."));
+  display_Update();
+
+  foldern = foldern + 1;
+  EEPROM_writeAnything(0, foldern);
+
+  if (!myFile.open(fileName, O_RDWR | O_CREAT)) {
+    print_Error(F("SD Error"), true);
+  }
+  read_setup_PCW();
+  for (unsigned long address = 0; address < 0x400000; address += 512) { // 4MB
+    for (unsigned int x = 0; x < 512; x++) {
+      sdBuffer[x] = read_rom_byte_PCW(address + x);
+    }
+    myFile.write(sdBuffer, 512);
+  }
+  myFile.flush();
+  myFile.close();
+
+  // Compare CRC32 to database and rename ROM if found
+  // Arguments: database name, precalculated crc string or 0 to calculate, rename rom or not, starting offset
+  compareCRC("pcw.txt", 0, 1, 0);
+
+  // Wait for user input
+  println_Msg(F(""));
+  println_Msg(F("Press Button..."));
+  display_Update();
+  wait();
+}
+
+void readMultiROM_PCW() {
+  strcpy(fileName, romName);
+  strcat(fileName, ".pcw");
+
+  EEPROM_readAnything(0, foldern);
+  sprintf(folder, "PCW/ROM/%d", foldern);
+  sd.mkdir(folder, true);
+  sd.chdir(folder);
+
+  display_Clear();
+  print_Msg(F("Saving to "));
+  print_Msg(folder);
+  println_Msg(F("/..."));
+  display_Update();
+
+  foldern = foldern + 1;
+  EEPROM_writeAnything(0, foldern);
+
+  if (!myFile.open(fileName, O_RDWR | O_CREAT)) {
+    print_Error(F("SD Error"), true);
+  }
+  display_Clear();
+  println_Msg(F("READING MULTI-PACK"));
+  println_Msg(F(""));
+  display_Update();
+  read_setup_PCW();
+  // Lower Half
+  switchBank_PCW(0);
+  for (unsigned long address = 0; address < 0x200000; address += 512) { // 2MB
+    for (unsigned int x = 0; x < 512; x++) {
+      sdBuffer[x] = read_rom_byte_PCW(address + x);
+    }
+    myFile.write(sdBuffer, 512);
+  }
+  read_setup_PCW();
+  // Upper Half
+  switchBank_PCW(1);
+  for (unsigned long address = 0x200000; address < 0x400000; address += 512) { // 2MB
+    for (unsigned int x = 0; x < 512; x++) {
+      sdBuffer[x] = read_rom_byte_PCW(address + x);
+    }
+    myFile.write(sdBuffer, 512);
+  }
+  myFile.flush();
+  myFile.close();
+  // Reset Bank
+  switchBank_PCW(0);
+
+  // Compare CRC32 to database and rename ROM if found
+  // Arguments: database name, precalculated crc string or 0 to calculate, rename rom or not, starting offset
+  compareCRC("pcw.txt", 0, 1, 0);
+
+  // Wait for user input
+  println_Msg(F(""));
+  println_Msg(F("Press Button..."));
+  display_Update();
+  wait();
+}
+
+//******************************************
+// SRAM
+//******************************************
+
+void readSRAM_PCW() { // readSRAM_1A()
+  strcpy(fileName, romName);
+  strcat(fileName, ".srm");
+
+  EEPROM_readAnything(0, foldern);
+  sprintf(folder, "PCW/SAVE/%d", foldern);
+  sd.mkdir(folder, true);
+  sd.chdir(folder);
+
+  foldern = foldern + 1;
+  EEPROM_writeAnything(0, foldern);
+
+  if (!myFile.open(fileName, O_RDWR | O_CREAT)) {
+    print_Error(F("SD Error"), true);
+  }
+  display_Clear();
+  read_setup_PCW();
+  for (unsigned long address = 0x0; address < 0x8000; address += 512) { // 32K
+    for (unsigned int x = 0; x < 512; x++) {
+      sdBuffer[x] = read_ram_byte_1A_PCW(address + x);
+    }
+    myFile.write(sdBuffer, 512);
+  }
+  myFile.flush();
+  myFile.close();
+  print_Msg(F("Saved to "));
+  print_Msg(folder);
+  println_Msg(F("/"));
+  display_Update();
+  //  calcCRC(fileName, 0x8000, NULL, 0); // 32K
+}
+
+// SRAM
+void writeSRAM_PCW() {
+  sprintf(filePath, "%s/%s", filePath, fileName);
+  println_Msg(F("Writing..."));
+  println_Msg(filePath);
+  display_Update();
+
+  if (myFile.open(filePath, O_READ)) {
+    sd.chdir();
+    sprintf(filePath, "%s/%s", filePath, fileName);
+    display_Clear();
+    println_Msg(F("Writing File: "));
+    println_Msg(filePath);
+    println_Msg(fileName);
+    display_Update();
+    //open file on sd card
+    if (myFile.open(filePath, O_READ)) {
+      read_setup_PCW();
+      for (unsigned int address = 0x0; address < 0x8000; address += 512) { // 32K
+        myFile.read(sdBuffer, 512);
+        for (unsigned int x = 0; x < 512; x++) {
+          write_ram_byte_1A_PCW(address + x, sdBuffer[x]);
+        }
+      }
+      myFile.close();
+      println_Msg(F("Done"));
+      display_Update();
+    }
+    else {
+      print_Error(F("SD Error"), true);
+    }
+  }
+  else {
+    print_Error(F("SD Error"), true);
+  }
+  display_Clear();
+}
+
+unsigned long verifySRAM_PCW() {
+  writeErrors = 0;
+
+  if (myFile.open(filePath, O_READ)) {
+    read_setup_PCW();
+    for (unsigned int address = 0x0; address < 0x8000; address += 512) { // 32K
+      for (unsigned int x = 0; x < 512; x++) {
+        byte myByte = read_ram_byte_1A_PCW(address + x);
+        sdBuffer[x] = myByte;
+      }
+      for (int i = 0; i < 512; i++) {
+        if (myFile.read() != sdBuffer[i]) {
+          writeErrors++;
+        }
+      }
+    }
+    myFile.close();
+  }
+  else {
+    print_Error(F("SD Error"), true);
+  }
+
+  return writeErrors;
+}

Cart_Reader/SNES.ino

@@ -1012,19 +1012,19 @@ boolean checkcart_SNES() {
     if (isprint(myByte) && myByte != '<' && myByte != '>' && myByte != ':' && myByte != '"' && myByte != '/' && myByte != '\\' && myByte != '|' && myByte != '?' && myByte != '*') {
       romName[myLength] = char(myByte);
     } else {
-      if (romName[myLength-1] == 0x5F) myLength--;
+      if (romName[myLength - 1] == 0x5F) myLength--;
       romName[myLength] = 0x5F;
     }
     myLength++;
   }
-  
+
   // Strip trailing white space
   for (unsigned int i = myLength - 1; i > 0; i--) {
     if ((romName[i] != 0x5F) && (romName[i] != 0x20)) break;
     romName[i] = 0x00;
     myLength--;
   }
-  
+
   // If name consists out of all japanese characters use game code
   if (myLength == 0) {
     // Get rom code

Cart_Reader/VBOY.ino

@@ -384,7 +384,7 @@ void readROM_VB() {
   strcpy(fileName, romName);
   strcat(fileName, ".vb");
 
-  EEPROM_readAnything(10, foldern);
+  EEPROM_readAnything(0, foldern);
   sprintf(folder, "VBOY/ROM/%s/%d", romName, foldern);
   sd.mkdir(folder, true);
   sd.chdir(folder);
@@ -396,7 +396,7 @@ void readROM_VB() {
   display_Update();
 
   foldern = foldern + 1;
-  EEPROM_writeAnything(10, foldern);
+  EEPROM_writeAnything(0, foldern);
 
   if (!myFile.open(fileName, O_RDWR | O_CREAT)) {
     print_Error(F("SD Error"), true);
@@ -482,13 +482,13 @@ void readSRAM_VB() {
   strcpy(fileName, romName);
   strcat(fileName, ".srm");
 
-  EEPROM_readAnything(10, foldern);
+  EEPROM_readAnything(0, foldern);
   sprintf(folder, "VBOY/SAVE/%s/%d", romName, foldern);
   sd.mkdir(folder, true);
   sd.chdir(folder);
 
   foldern = foldern + 1;
-  EEPROM_writeAnything(10, foldern);
+  EEPROM_writeAnything(0, foldern);
 
   if (!myFile.open(fileName, O_RDWR | O_CREAT)) {
     print_Error(F("SD Error"), true);