mirror of
https://github.com/cemu-project/Cemu.git
synced 2024-11-25 02:26:54 +01:00
237 lines
8.9 KiB
CMake
237 lines
8.9 KiB
CMake
|
vcpkg_from_github(
|
||
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
||
|
|
REPO wxWidgets/wxWidgets
|
||
|
|
REF v3.2.0
|
||
|
|
SHA512 0bb40ccab51f5e83a38feeaf462c9d1852f821d19592328327f829890d89a3abb2a991c43cdbac55da8f5ee40aab8bd5fea6abcd052198302770292f92f9f9ad
|
||
|
|
HEAD_REF master
|
||
|
|
PATCHES
|
||
|
|
install-layout.patch
|
||
|
|
relocatable-wx-config.patch
|
||
|
|
fix-libs-export.patch
|
||
|
|
fix-pcre2.patch
|
||
|
|
gtk3-link-libraries.patch
|
||
|
|
)
|
||
|
|
|
||
|
|
if(VCPKG_TARGET_IS_LINUX)
|
||
|
|
message(WARNING [[
|
||
|
|
Port wxwidgets currently requires the following packages from the system package manager:
|
||
|
|
pkg-config
|
||
|
|
GTK 3
|
||
|
|
libsecret
|
||
|
|
libgcrypt
|
||
|
|
libsystemd
|
||
|
|
These development packages can be installed on Ubuntu systems via
|
||
|
|
sudo apt-get install pkg-config libgtk-3-dev libsecret-1-dev libgcrypt20-dev libsystemd-dev
|
||
|
|
]])
|
||
|
|
foreach(conflicting_port IN ITEMS freetype glib)
|
||
|
|
if(EXISTS "${CURRENT_INSTALLED_DIR}/share/${conflicting_port}/copyright")
|
||
|
|
message(FATAL_ERROR "Port ${conflicting_port} must not be installed when building ${PORT}:${TARGET_TRIPLET}.")
|
||
|
|
endif()
|
||
|
|
endforeach()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
vcpkg_check_features(
|
||
|
|
OUT_FEATURE_OPTIONS FEATURE_OPTIONS
|
||
|
|
FEATURES
|
||
|
|
sound wxUSE_SOUND
|
||
|
|
fonts wxUSE_PRIVATE_FONTS
|
||
|
|
)
|
||
|
|
|
||
|
|
set(OPTIONS_RELEASE "")
|
||
|
|
if(NOT "debug-support" IN_LIST FEATURES)
|
||
|
|
list(APPEND OPTIONS_RELEASE "-DwxBUILD_DEBUG_LEVEL=0")
|
||
|
|
endif()
|
||
|
|
|
||
|
|
set(OPTIONS "")
|
||
|
|
if(VCPKG_TARGET_IS_WINDOWS AND (VCPKG_TARGET_ARCHITECTURE STREQUAL "arm64" OR VCPKG_TARGET_ARCHITECTURE STREQUAL "arm"))
|
||
|
|
list(APPEND OPTIONS
|
||
|
|
-DwxUSE_OPENGL=OFF
|
||
|
|
-DwxUSE_STACKWALKER=OFF
|
||
|
|
)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(VCPKG_TARGET_IS_WINDOWS OR VCPKG_TARGET_IS_OSX)
|
||
|
|
list(APPEND OPTIONS -DwxUSE_WEBREQUEST_CURL=OFF)
|
||
|
|
else()
|
||
|
|
list(APPEND OPTIONS -DwxUSE_WEBREQUEST_CURL=ON)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(DEFINED ENV{PKG_CONFIG})
|
||
|
|
set(PKGCONFIG "$ENV{PKG_CONFIG}")
|
||
|
|
elseif(VCPKG_TARGET_IS_LINUX AND NOT VCPKG_CROSSCOMPILING)
|
||
|
|
# wxWidgets on Linux currently needs to find the system's `gtk+-3.0.pc`.
|
||
|
|
# vcpkg's port pkgconf would prevent this lookup.
|
||
|
|
find_program(system_pkg_config NAMES pkg-config)
|
||
|
|
if(system_pkg_config)
|
||
|
|
set(PKGCONFIG "${system_pkg_config}")
|
||
|
|
endif()
|
||
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
||
|
|
list(APPEND OPTIONS -DPKG_CONFIG_ARGN=--static)
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
vcpkg_find_acquire_program(PKGCONFIG)
|
||
|
|
|
||
|
|
# This may be set to ON by users in a custom triplet.
|
||
|
|
# The use of 'wxUSE_STL' and 'WXWIDGETS_USE_STD_CONTAINERS' (ON or OFF) are not API compatible
|
||
|
|
# which is why they must be set in a custom triplet rather than a port feature.
|
||
|
|
if(NOT DEFINED WXWIDGETS_USE_STL)
|
||
|
|
#set(WXWIDGETS_USE_STL OFF)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(NOT DEFINED WXWIDGETS_USE_STD_CONTAINERS)
|
||
|
|
set(WXWIDGETS_USE_STD_CONTAINERS OFF)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
vcpkg_cmake_configure(
|
||
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
||
|
|
OPTIONS
|
||
|
|
${FEATURE_OPTIONS}
|
||
|
|
-DwxUSE_REGEX=sys
|
||
|
|
-DwxUSE_ZLIB=sys
|
||
|
|
-DwxUSE_EXPAT=sys
|
||
|
|
-DwxUSE_LIBJPEG=sys
|
||
|
|
-DwxUSE_LIBPNG=sys
|
||
|
|
-DwxUSE_LIBTIFF=sys
|
||
|
|
-DwxUSE_SECRETSTORE=FALSE
|
||
|
|
-DwxUSE_STL=ON
|
||
|
|
-DwxUSE_STD_CONTAINERS=${WXWIDGETS_USE_STD_CONTAINERS}
|
||
|
|
-DwxBUILD_DISABLE_PLATFORM_LIB_DIR=ON
|
||
|
|
-DwxUSE_LIBLZMA=OFF
|
||
|
|
-DwxUSE_JOYSTICK=OFF
|
||
|
|
-DwxUSE_SOCKETS=OFF
|
||
|
|
-DwxUSE_IPV6=OFF
|
||
|
|
-DwxUSE_FS_ZIP=OFF
|
||
|
|
-DwxUSE_FS_ARCHIVE=OFF
|
||
|
|
-DwxUSE_FS_INET=OFF
|
||
|
|
-DwxUSE_ARCHIVE_STREAMS=OFF
|
||
|
|
-DwxUSE_ZIPSTREAM=OFF
|
||
|
|
-DwxUSE_TARSTREAM=OFF
|
||
|
|
-DwxUSE_PROTOCOL=OFF
|
||
|
|
-DwxUSE_PROTOCOL_FTP=OFF
|
||
|
|
-DwxUSE_PROTOCOL_HTTP=OFF
|
||
|
|
-DwxUSE_URL=OFF
|
||
|
|
-DwxUSE_SOUND=OFF
|
||
|
|
-DwxUSE_WEBVIEW=OFF
|
||
|
|
-DwxUSE_RICHTEXT=OFF
|
||
|
|
-DwxUSE_SVG=OFF
|
||
|
|
-DwxUSE_GIF=OFF
|
||
|
|
-DwxUSE_PNM=OFF
|
||
|
|
-DwxUSE_PCX=OFF
|
||
|
|
-DwxUSE_WEBREQUEST=OFF
|
||
|
|
-DwxUSE_ACTIVEX=OFF
|
||
|
|
-DwxUSE_REGEX=OFF
|
||
|
|
-DwxUSE_NANOSVG=OFF
|
||
|
|
-DwxUSE_NANOSVG_EXTERNAL=OFF
|
||
|
|
${OPTIONS}
|
||
|
|
"-DPKG_CONFIG_EXECUTABLE=${PKGCONFIG}"
|
||
|
|
# The minimum cmake version requirement for Cotire is 2.8.12.
|
||
|
|
# however, we need to declare that the minimum cmake version requirement is at least 3.1 to use CMAKE_PREFIX_PATH as the path to find .pc.
|
||
|
|
-DPKG_CONFIG_USE_CMAKE_PREFIX_PATH=ON
|
||
|
|
OPTIONS_RELEASE
|
||
|
|
${OPTIONS_RELEASE}
|
||
|
|
)
|
||
|
|
|
||
|
|
vcpkg_cmake_install()
|
||
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/wxWidgets)
|
||
|
|
|
||
|
|
# The CMake export is not ready for use: It lacks a config file.
|
||
|
|
file(REMOVE_RECURSE
|
||
|
|
${CURRENT_PACKAGES_DIR}/lib/cmake
|
||
|
|
${CURRENT_PACKAGES_DIR}/debug/lib/cmake
|
||
|
|
)
|
||
|
|
|
||
|
|
set(tools wxrc)
|
||
|
|
if(NOT VCPKG_TARGET_IS_WINDOWS OR NOT VCPKG_HOST_IS_WINDOWS)
|
||
|
|
list(APPEND tools wxrc-3.2)
|
||
|
|
file(MAKE_DIRECTORY "${CURRENT_PACKAGES_DIR}/tools/${PORT}")
|
||
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}/bin/wx-config" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/wx-config")
|
||
|
|
if(NOT VCPKG_BUILD_TYPE)
|
||
|
|
file(MAKE_DIRECTORY "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug")
|
||
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}/debug/bin/wx-config" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug/wx-config")
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
vcpkg_copy_tools(TOOL_NAMES ${tools} AUTO_CLEAN)
|
||
|
|
|
||
|
|
# do the copy pdbs now after the dlls got moved to the expected /bin folder above
|
||
|
|
vcpkg_copy_pdbs()
|
||
|
|
|
||
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/msvc")
|
||
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
|
||
|
|
file(GLOB_RECURSE INCLUDES "${CURRENT_PACKAGES_DIR}/include/*.h")
|
||
|
|
if(EXISTS "${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h")
|
||
|
|
list(APPEND INCLUDES "${CURRENT_PACKAGES_DIR}/lib/mswu/wx/setup.h")
|
||
|
|
endif()
|
||
|
|
if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
|
||
|
|
list(APPEND INCLUDES "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
|
||
|
|
endif()
|
||
|
|
foreach(INC IN LISTS INCLUDES)
|
||
|
|
file(READ "${INC}" _contents)
|
||
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
||
|
|
string(REPLACE "defined(WXUSINGDLL)" "0" _contents "${_contents}")
|
||
|
|
else()
|
||
|
|
string(REPLACE "defined(WXUSINGDLL)" "1" _contents "${_contents}")
|
||
|
|
endif()
|
||
|
|
# Remove install prefix from setup.h to ensure package is relocatable
|
||
|
|
string(REGEX REPLACE "\n#define wxINSTALL_PREFIX [^\n]*" "\n#define wxINSTALL_PREFIX \"\"" _contents "${_contents}")
|
||
|
|
file(WRITE "${INC}" "${_contents}")
|
||
|
|
endforeach()
|
||
|
|
|
||
|
|
if(NOT EXISTS "${CURRENT_PACKAGES_DIR}/include/wx/setup.h")
|
||
|
|
file(GLOB_RECURSE WX_SETUP_H_FILES_DBG "${CURRENT_PACKAGES_DIR}/debug/lib/*.h")
|
||
|
|
file(GLOB_RECURSE WX_SETUP_H_FILES_REL "${CURRENT_PACKAGES_DIR}/lib/*.h")
|
||
|
|
|
||
|
|
if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "release")
|
||
|
|
vcpkg_replace_string("${WX_SETUP_H_FILES_REL}" "${CURRENT_PACKAGES_DIR}" "")
|
||
|
|
|
||
|
|
string(REPLACE "${CURRENT_PACKAGES_DIR}/lib/" "" WX_SETUP_H_FILES_REL "${WX_SETUP_H_FILES_REL}")
|
||
|
|
string(REPLACE "/setup.h" "" WX_SETUP_H_REL_RELATIVE "${WX_SETUP_H_FILES_REL}")
|
||
|
|
endif()
|
||
|
|
if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL "debug")
|
||
|
|
vcpkg_replace_string("${WX_SETUP_H_FILES_DBG}" "${CURRENT_PACKAGES_DIR}" "")
|
||
|
|
|
||
|
|
string(REPLACE "${CURRENT_PACKAGES_DIR}/debug/lib/" "" WX_SETUP_H_FILES_DBG "${WX_SETUP_H_FILES_DBG}")
|
||
|
|
string(REPLACE "/setup.h" "" WX_SETUP_H_DBG_RELATIVE "${WX_SETUP_H_FILES_DBG}")
|
||
|
|
endif()
|
||
|
|
|
||
|
|
configure_file("${CMAKE_CURRENT_LIST_DIR}/setup.h.in" "${CURRENT_PACKAGES_DIR}/include/wx/setup.h" @ONLY)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
file(GLOB configs LIST_DIRECTORIES false "${CURRENT_PACKAGES_DIR}/lib/wx/config/*" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/wx-config")
|
||
|
|
foreach(config IN LISTS configs)
|
||
|
|
vcpkg_replace_string("${config}" "${CURRENT_INSTALLED_DIR}" [[${prefix}]])
|
||
|
|
endforeach()
|
||
|
|
file(GLOB configs LIST_DIRECTORIES false "${CURRENT_PACKAGES_DIR}/debug/lib/wx/config/*" "${CURRENT_PACKAGES_DIR}/tools/${PORT}/debug/wx-config")
|
||
|
|
foreach(config IN LISTS configs)
|
||
|
|
vcpkg_replace_string("${config}" "${CURRENT_INSTALLED_DIR}/debug" [[${prefix}]])
|
||
|
|
endforeach()
|
||
|
|
|
||
|
|
# For CMake multi-config in connection with wrapper
|
||
|
|
if(EXISTS "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h")
|
||
|
|
file(INSTALL "${CURRENT_PACKAGES_DIR}/debug/lib/mswud/wx/setup.h"
|
||
|
|
DESTINATION "${CURRENT_PACKAGES_DIR}/lib/mswud/wx"
|
||
|
|
)
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if(NOT "debug-support" IN_LIST FEATURES)
|
||
|
|
if(VCPKG_TARGET_IS_WINDOWS AND VCPKG_HOST_IS_WINDOWS)
|
||
|
|
vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/wx/debug.h" "#define wxDEBUG_LEVEL 1" "#define wxDEBUG_LEVEL 0")
|
||
|
|
else()
|
||
|
|
vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/wx-3.2/wx/debug.h" "#define wxDEBUG_LEVEL 1" "#define wxDEBUG_LEVEL 0")
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
|
||
|
|
if("example" IN_LIST FEATURES)
|
||
|
|
file(INSTALL
|
||
|
|
"${CMAKE_CURRENT_LIST_DIR}/example/CMakeLists.txt"
|
||
|
|
"${SOURCE_PATH}/samples/popup/popup.cpp"
|
||
|
|
"${SOURCE_PATH}/samples/sample.xpm"
|
||
|
|
DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}/example"
|
||
|
|
)
|
||
|
|
vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/share/${PORT}/example/popup.cpp" "../sample.xpm" "sample.xpm")
|
||
|
|
endif()
|
||
|
|
|
||
|
|
configure_file("${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
|
||
|
|
|
||
|
|
file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
|
||
|
|
file(INSTALL "${SOURCE_PATH}/docs/licence.txt" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
|